Dx21 - ADSI

Home

eZine

Coding

Software

Network Admin.

Home > Coding > Scripting > ADSI > Mapping - User

	UDF / UDC Library
	Script Library

AD GUI to Property Map: User Object
Click A Tab To Navigate
	General

Property Mapping

RO	GUI Control	ADSI Property
X	{User ID}	name
	Full name	givenName
	Initials	initials
	Last name	sn
	Display name	displayName
	Description	description
	Office	physicalDeliveryOfficeName
	Telephone Number	telephoneNumber
	Telephone Number Other Button	otherTelephone
	E-mail	mail
	Web page	wWWHomePage
	Web page Other Button	url

Property Write Example Script

Option Explicit

Const ADS_PROPERTY_CLEAR = 1
Const ADS_PROPERTY_UPDATE = 2
Const ADS_PROPERTY_APPEND = 3
Const ADS_PROPERTY_DELETE = 4

Dim objUser, objRDSE
Dim colItems, objItem

'Change LDAP path as needed

Set objRDSE = GetObject("LDAP://rootDSE")
Set objUser = GetObject("LDAP://cn=[UserID]," & _
	"cn=Users," & objRDSE.Get("defaultNamingContext"))

WScript.Echo "GENERAL PROPERTIES PAGE"
WScript.Echo String(45, "/")
WScript.Echo "(Single Valued Attributes)"
WScript.Echo String(45, "-")
WScript.Echo 

'Change Values as needed
WScript.Echo "First name:........FirstName"
objUser.Put "givenName", "FirstName"
objUser.SetInfo
WScript.Echo "Initials:..........XXX"
objUser.Put "initials", "XXX"
objUser.SetInfo
WScript.Echo "Last name:.........LastName"
objUser.Put "sn", "LastName"
objUser.SetInfo
WScript.Echo "Display name:......LastName, FirstName MI"
objUser.Put "displayName", "LastName, FirstName MI"
objUser.SetInfo
WScript.Echo "Description:.......Generic Description"
objUser.Put "description", "Generic Description"
objUser.SetInfo
WScript.Echo "Office:............City"
objUser.Put "physicalDeliveryOfficeName", "SCity"
objUser.SetInfo
WScript.Echo "Telephone number:..800-555-1212"
objUser.Put "telephoneNumber", "800-555-1212"
objUser.SetInfo
WScript.Echo "E-Mail:............[UserID]@[Host].com"
objUser.Put "mail", "[UserID]@[Host].com"
objUser.SetInfo
WScript.Echo "Web page:..........http://www.[Host].com/[UserID]"
objUser.Put "wWWHomePage", "http://www.[Host].com/[UserID]"
objUser.SetInfo
WScript.Echo 

'Delete a Single Valued Attribute
WScript.Echo "** Clearing the Web page Data."
objUser.PutEx ADS_PROPERTY_CLEAR, "wWWHomePage", vbNullString
objUser.SetInfo

WScript.Echo
WScript.Echo "(MultiValued Attributes)"
WScript.Echo String(45, "-")
WScript.Echo

WScript.Echo "Phone Numbers (Others):"
WScript.Echo "Clearing all existing numbers."
	objUser.PutEx ADS_PROPERTY_CLEAR, "otherTelephone", vbNullString
	objUser.SetInfo
WScript.Echo "Adding: 000-000-0000, 111-111-1111, 222-222-2222"
	objUser.PutEx ADS_PROPERTY_UPDATE, "otherTelephone", _
		Array("000-000-0000", "111-111-1111", "222-222-2222")
	objUser.SetInfo
WScript.Echo "Removing specific number: 111-111-1111"
	objUser.PutEx ADS_PROPERTY_DELETE, "otherTelephone", _
		Array("111-111-1111")
	objUser.SetInfo
WScript.Echo "Appending new number: 333-333-3333"
	objUser.PutEx ADS_PROPERTY_APPEND, "otherTelephone", _
		Array("333-333-3333")
	objUser.SetInfo
WScript.Echo

WScript.Echo "Web Page Address (Others):"
WScript.Echo "{Skipped}"
'This works exactly the same as the Phone Numbers above,
'but substitute the 'otherTelephone' with 'url'.
WScript.Echo

Set objUser = Nothing
Set objRDSE = Nothing

	FAQs \| Terms Of Use \| Privacy Policy \| Contact Us
	Copyright © 1997 - 2012 Dx21, LLC. All rights reserved. Dx21, LLC a Washington Limited Liability Company Page Rendered at: 2/5/2012 5:06:29 AM for Unknown

General

Property Mapping

Property Read Example Script

Property Write Example Script